cry386i/oh_my_little_overlay
1
0
Fork 0
Code Activity

first commit

Browse source
This commit is contained in:
root 2024-11-23 01:15:11 +02:00
commit 528f89a79b
90 changed files with 13567 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

1
media-libs/fmod/Manifest Normal file
View file

@ -0,0 +1 @@
DIST fmodapi44464linux.tar.gz 25520093 BLAKE2B 4a702aed24c1a42d35462341290a1c71717e208229c640931c06b9d80580f4e5f0b984ab2c7ee024defc1dc7b9d0e21bd13c1148a2814e1e3bb3aea0f8409f6a SHA512 af365f82eea8b7e38bb8c3910470b28626ac58d46ae8122bbdaf51b5339810504cd0f541334c5e989180b3a6b2ecdcf7bc82c00ce3ef1f6af5278df20a20d611

48
media-libs/fmod/fmod-4.44.64.ebuild Normal file
View file

@ -0,0 +1,48 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
MY_PV=$(ver_rs 1- '')
DESCRIPTION="Libraries of the fmodex audio engine"
HOMEPAGE="https://zdoom.org/files/fmod/ https://www.fmod.com/"
SRC_URI="https://zdoom.org/files/fmod/fmodapi${MY_PV}linux.tar.gz"
S="${WORKDIR}/fmodapi${MY_PV}linux"
# Ogg Vorbis: BSD
# Android: BSD-2
LICENSE="BSD BSD-2 fmod"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RESTRICT="strip test"
QA_PREBUILT="*"
src_compile() { :; }
src_install() {
cd "${S}/api/lib/" || die
for lib in libfmodex libfmodexL
do
dolib.so ${lib}64-${PV}.so
dolib.so ${lib}64.so
dolib.so ${lib}-${PV}.so
dolib.so ${lib}.so
done
cd "${S}/fmoddesignerapi/api/lib/" || die
for lib in libfmodevent libfmodeventL libfmodeventnet libfmodeventnetL
do
dolib.so ${lib}64-${PV}.so
dolib.so ${lib}64.so
dolib.so ${lib}-${PV}.so
dolib.so ${lib}.so
done
cd "${S}/api/inc/" || die
doheader *
cd "${S}/fmoddesignerapi/api/inc/" || die
doheader *
}

1
media-libs/libsdl3/Manifest Normal file
View file

@ -0,0 +1 @@
DIST libsdl3-3.1.6.tar.gz 7773892 BLAKE2B 6701e4d65816bc2845096f69479ca2759a24c365d1bb25be2e7588b96dbe9eeec1eb7e7031d1b72911fbe198d3358f67feb308a23cc8cc80e509731dddda8b1b SHA512 a0ca7263cd2f1b883829c39ae0ee2ea18d814f8dde768c8be9a49487193bc856bb45870764fd70169e75d2ec80457e5b45811c07a926479f1ac4f9d3157f40a4

203
media-libs/libsdl3/libsdl3-3.1.6.ebuild Normal file
View file

@ -0,0 +1,203 @@
# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake-multilib flag-o-matic
DESCRIPTION="Simple Direct Media Layer"
HOMEPAGE="https://www.libsdl.org/"
SRC_URI="https://github.com/libsdl-org/SDL/archive/refs/tags/preview-${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/SDL-preview-${PV}"
LICENSE="ZLIB"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~x86"
IUSE="X alsa +sound cpu_flags_x86_avx cpu_flags_x86_avx2 cpu_flags_x86_avx512f cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 \
cpu_flags_x86_sse3 cpu_flags_x86_sse4_1 cpu_flags_x86_sse4_2 camera custom-cflags dbus debug doc gles1 gles2 +haptic ibus \
jack +joystick kms opengl pipewire pulseaudio sndio static-libs \
test udev +video vulkan wayland xscreensaver"
RESTRICT="!test? ( test )"
REQUIRED_USE="
alsa? ( sound )
haptic? ( joystick )
ibus? ( dbus )
jack? ( sound )
gles1? ( video )
gles2? ( video )
opengl? ( video )
pipewire? ( sound )
pulseaudio? ( sound )
sndio? ( sound )
vulkan? ( video )
wayland? ( gles2 )
xscreensaver? ( X )
"
COMMON_DEPEND="
X? (
>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
>=x11-libs/libXcursor-1.1.14[${MULTILIB_USEDEP}]
>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
>=x11-libs/libXfixes-6.0.0[${MULTILIB_USEDEP}]
>=x11-libs/libXi-1.7.2[${MULTILIB_USEDEP}]
>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
xscreensaver? ( >=x11-libs/libXScrnSaver-1.2.2-r1[${MULTILIB_USEDEP}] )
)
alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
dbus? ( >=sys-apps/dbus-1.6.18-r1[${MULTILIB_USEDEP}] )
ibus? ( app-i18n/ibus )
jack? ( virtual/jack[${MULTILIB_USEDEP}] )
kms? (
>=x11-libs/libdrm-2.4.82[${MULTILIB_USEDEP}]
>=media-libs/mesa-9.0.0[${MULTILIB_USEDEP}]
)
opengl? (
>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
>=virtual/glu-9.0-r1[${MULTILIB_USEDEP}]
)
pipewire? ( media-video/pipewire:=[${MULTILIB_USEDEP}] )
pulseaudio? ( media-libs/libpulse[${MULTILIB_USEDEP}] )
sndio? ( media-sound/sndio:=[${MULTILIB_USEDEP}] )
udev? ( >=virtual/libudev-208:=[${MULTILIB_USEDEP}] )
virtual/libiconv[${MULTILIB_USEDEP}]
wayland? (
>=dev-libs/wayland-1.20[${MULTILIB_USEDEP}]
gui-libs/libdecor[${MULTILIB_USEDEP}]
>=media-libs/mesa-9.1.6[${MULTILIB_USEDEP},wayland]
>=x11-libs/libxkbcommon-0.2.0[${MULTILIB_USEDEP}]
)
"
RDEPEND="
${COMMON_DEPEND}
opengl? ( media-libs/mesa[${MULTILIB_USEDEP},opengl(+)] )
vulkan? (
media-libs/mesa[${MULTILIB_USEDEP},vulkan(+)]
vulkan? ( media-libs/vulkan-loader[${MULTILIB_USEDEP}] )
)
"
DEPEND="
${COMMON_DEPEND}
gles1? ( media-libs/libglvnd )
gles2? ( media-libs/libglvnd )
ibus? ( dev-libs/glib:2 )
test? ( x11-libs/libX11[${MULTILIB_USEDEP}] )
vulkan? ( dev-util/vulkan-headers )
X? ( x11-base/xorg-proto )
"
BDEPEND="
virtual/pkgconfig
doc? (
app-text/doxygen
media-gfx/graphviz
)
wayland? ( >=dev-util/wayland-scanner-1.20 )
"
src_prepare() {
cmake_src_prepare
# Unbundle some headers.
rm -r src/video/khronos || die
ln -s "${ESYSROOT}/usr/include" src/video/khronos || die
}
src_configure() {
use custom-cflags || strip-flags
local mycmakeargs=(
-DSDL_ALSA=$(usex alsa)
-DSDL_ALSA_SHARED=OFF
-DSDL_ASAN=$(usex debug)
-DSDL_ASSEMBLY=ON
-DSDL_ASSERTIONS=$(usex debug enabled disabled)
-DSDL_AUDIO=$(usex sound)
-DSDL_AVX=$(usex cpu_flags_x86_avx)
-DSDL_AVX2=$(usex cpu_flags_x86_avx2)
-DSDL_AVX512F=$(usex cpu_flags_x86_avx512f)
-DSDL_CAMERA=$(usex camera)
-DSDL_CCACHE=OFF
-DSDL_DBUS=$(usex dbus)
-DSDL_DIALOG=ON
-DSDL_DISABLE_INSTALL=OFF
-DSDL_DISABLE_INSTALL_CPACK=OFF
-DSDL_DISABLE_INSTALL_DOCS=$(usex doc OFF ON)
-DSDL_DISKAUDIO=$(usex sound)
-DSDL_DUMMYAUDIO=$(use sound)
-DSDL_DUMMYCAMERA=$(use camera)
-DSDL_DUMMYVIDEO=$(use video)
-DSDL_EXAMPLES=$(usex doc)
-DSDL_EXAMPLES_LINK_SHARED=OFF
-DSDL_GCC_ATOMICS=ON
-DSDL_GPU=$(usex video)
-DSDL_HAPTIC=$(usex haptic)
-DSDL_IBUS=$(usex ibus)
-DSDL_JACK=$(usex jack)
-DSDL_JACK_SHARED=OFF
-DSDL_JOYSTICK=$(usex joystick)
-DSDL_HIDAPI=ON
-DSDL_KMSDRM=$(usex kms)
-DSDL_KMSDRM_SHARED=OFF
-DSDL_LIBC=ON
-DSDL_LIBICONV=ON
-DSDL_SYSTEM_ICONV=ON
-DSDL_LIBUDEV=$(usex udev)
-DSDL_MMX=$(usex cpu_flags_x86_mmx)
-DSDL_OPENGL=$(usex opengl)
-DSDL_OPENGLES=$(usex gles1 || usex gles2 && echo ON || echo OFF)
-DSDL_PIPEWIRE=$(usex pipewire)
-DSDL_PIPEWIRE_SHARED=OFF
-DSDL_PULSEAUDIO=$(usex pulseaudio)
-DSDL_PULSEAUDIO_SHARED=OFF
-DSDL_RENDER=$(use video)
-DSDL_RENDER_GPU=$(use video)
-DSDL_RENDER_VULKAN=$(usex vulkan)
-DSDL_RPATH=OFF
-DSDL_RPI=OFF
-DSDL_SNDIO=$(usex sndio)
-DSDL_SNDIO_SHARED=OFF
-DSDL_SSE=$(usex cpu_flags_x86_sse)
-DSDL_SSE2=$(usex cpu_flags_x86_sse2)
-DSDL_SSE3=$(usex cpu_flags_x86_sse3)
-DSDL_SSE4_1=$(usex cpu_flags_x86_sse4_1)
-DSDL_SSE4_2=$(usex cpu_flags_x86_sse4_2)
-DSDL_STATIC=$(usex static-libs)
-DSDL_TESTS=$(usex test)
-DSDL_TESTS_LINK_SHARED=OFF
-DSDL_TEST_LIBRARY=$(usex test)
-DSDL_VIDEO=$(usex video)
-DSDL_VIRTUAL_JOYSTICK=$(usex joystick)
-DSDL_VULKAN=$(usex vulkan)
-DSDL_WAYLAND=$(usex wayland)
-DSDL_WAYLAND_LIBDECOR=$(usex wayland)
-DSDL_WAYLAND_LIBDECOR_SHARED=OFF
-DSDL_WAYLAND_SHARED=OFF
-DSDL_WERROR=$(usex debug)
-DSDL_X11=$(usex X)
-DSDL_X11_SHARED=OFF
-DSDL_X11_XSCRNSAVER=$(usex xscreensaver)
)
cmake-multilib_src_configure
}
src_compile() {
cmake-multilib_src_compile
if use doc; then
cd docs || die
doxygen || die
fi
}
src_test() {
unset SDL_GAMECONTROLLERCONFIG SDL_GAMECONTROLLER_USE_BUTTON_LABELS
cmake-multilib_src_test
}
multilib_src_install_all() {
rm -r "${ED}"/usr/share/licenses/ || die
dodoc {BUGS,README-SDL,WhatsNew}.txt CREDITS.md README.md docs/README*.md
use doc && dodoc -r docs/output/html/
}

37
media-libs/libsdl3/metadata.xml Normal file
View file

@ -0,0 +1,37 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer type="person">
<email>noreply@local</email>
<name>nil</name>
</maintainer>
<longdescription>
Simple DirectMedia Layer is a cross-platform multimedia library
designed to provide low level access to audio, keyboard, mouse,
joystick, 3D hardware via OpenGL, and 2D video framebuffer. It is
used by MPEG playback software, emulators, and many popular games,
including the award winning Linux port of "Civilization: Call To
Power."
Simple DirectMedia Layer supports Linux, Windows, BeOS, MacOS
Classic, MacOS X, FreeBSD, OpenBSD, BSD/OS, Solaris, IRIX, and QNX.
There is also code, but no official support, for Windows CE,
AmigaOS, Dreamcast, Atari, NetBSD, AIX, OSF/Tru64, RISC OS, and
SymbianOS.
SDL is written in C, but works with C++ natively, and has bindings
to several other languages, including Ada, Eiffel, Java, Lua, ML,
Perl, PHP, Pike, Python, and Ruby.
</longdescription>
<use>
<flag name="camera">Enable camera subsystem.</flag>
<flag name="video">Control video support (disable at your own risk).</flag>
<flag name="sound">Control audio support (disable at your own risk).</flag>
<flag name="gles1">Include OpenGL ES 1.0 support.</flag>
<flag name="haptic">Enable the haptic (force feedback) subsystem</flag>
<flag name="sndio">Enable support for the <pkg>media-sound/sndio</pkg> backend</flag>
<flag name="pipewire">Enable support for the <pkg>media-video/pipewire</pkg> audio backend</flag>
<flag name="ibus">Enable support for app-i18n/ibus.</flag>
<flag name="kms">Build the KMSDRM video driver.</flag>
</use>
</pkgmetadata>

1
media-libs/raylib/Manifest Normal file
View file

@ -0,0 +1 @@
DIST raylib-5.0.tar.gz 32701105 BLAKE2B ee8ef069cd2a7b91efd1d97e8ed9076620c216fb0bf2eb7517624472d157c2d20919a6c54d7f8160e34c1d1a889f1766f5a94c6577bbb68f779e76a5160229dd SHA512 5956bc1646b99baac6eb1652c4d72e96af874337158672155ba144f131de8a4fd19291a58335a92fcaaa2fc818682f93ff4230af0f815efb8b49f7d2a162e9b0

19
media-libs/raylib/metadata.xml Normal file
View file

@ -0,0 +1,19 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer type="person">
<email>noreply@local</email>
<name>nil</name>
</maintainer>
<use>
<flag name="alsa">Add support for media-libs/alsa-lib (Advanced Linux Sound Architecture).</flag>
<flag name="examples">Build and install examples.</flag>
<flag name="static-libs">Build static version of dynamic libraries as well.</flag>
<flag name="system-glfw">Use system glfw instead of build it.</flag>
<flag name="X">Add support for X11.</flag>
<flag name="wayland">Enable dev-libs/wayland backend.</flag>
</use>
<description>
raylib is a simple and easy-to-use library to enjoy videogames programming.
</description>
</pkgmetadata>

65
media-libs/raylib/raylib-5.0.ebuild Normal file
View file

@ -0,0 +1,65 @@
# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake
DESCRIPTION="A simple and easy-to-use library to learn videogames programming"
HOMEPAGE="https://www.raylib.com/"
LICENSE="ZLIB"
SLOT="0"
IUSE="alsa examples static-libs +system-glfw +X wayland"
REQUIRED_USE="|| ( system-glfw || ( X wayland ) )"
if [[ ${PV} == *9999 ]] ; then
EGIT_REPO_URI="https://github.com/raysan5/raylib.git"
inherit git-r3
else
SRC_URI="https://github.com/raysan5/raylib/archive/${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64"
S="${WORKDIR}/raylib-${PV}"
fi
RDEPEND="
alsa? ( media-libs/alsa-lib )
X? (
virtual/opengl
x11-libs/libX11
x11-libs/libXcursor
x11-libs/libXi
x11-libs/libXinerama
x11-libs/libXrandr
x11-libs/libXxf86vm
)
wayland? (
dev-libs/wayland
media-libs/mesa[wayland]
)
system-glfw? ( >=media-libs/glfw-3.2.1 )
"
DEPEND="${RDEPEND}"
src_configure() {
local mycmakeargs=(
-DBUILD_SHARED_LIBS=$(usex !static-libs ON OFF)
-DUSE_AUDIO=$(usex alsa ON OFF)
-DUSE_EXTERNAL_GLFW=$(usex system-glfw ON OFF)
-DBUILD_EXAMPLES=OFF
)
if use !system-glfw; then
mycmakeargs+=(-DGLFW_BUILD_WAYLAND=$(usex wayland ON OFF))
mycmakeargs+=(-DGLFW_BUILD_X11=$(usex X ON OFF))
fi
cmake_src_configure
}
src_install() {
cmake_src_install
if use examples; then
dodoc -r "${S}"/examples/*
fi
}

65
media-libs/raylib/raylib-9999.ebuild Normal file
View file

@ -0,0 +1,65 @@
# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake
DESCRIPTION="A simple and easy-to-use library to learn videogames programming"
HOMEPAGE="https://www.raylib.com/"
LICENSE="ZLIB"
SLOT="0"
IUSE="alsa examples static-libs +system-glfw +X wayland"
REQUIRED_USE="|| ( system-glfw || ( X wayland ) )"
if [[ ${PV} == *9999 ]] ; then
EGIT_REPO_URI="https://github.com/raysan5/raylib.git"
inherit git-r3
else
SRC_URI="https://github.com/raysan5/raylib/archive/${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64"
S="${WORKDIR}/raylib-${PV}"
fi
RDEPEND="
alsa? ( media-libs/alsa-lib )
X? (
virtual/opengl
x11-libs/libX11
x11-libs/libXcursor
x11-libs/libXi
x11-libs/libXinerama
x11-libs/libXrandr
x11-libs/libXxf86vm
)
wayland? (
dev-libs/wayland
media-libs/mesa[wayland]
)
system-glfw? ( >=media-libs/glfw-3.2.1 )
"
DEPEND="${RDEPEND}"
src_configure() {
local mycmakeargs=(
-DBUILD_SHARED_LIBS=$(usex !static-libs ON OFF)
-DUSE_AUDIO=$(usex alsa ON OFF)
-DUSE_EXTERNAL_GLFW=$(usex system-glfw ON OFF)
-DBUILD_EXAMPLES=OFF
)
if use !system-glfw; then
mycmakeargs+=(-DGLFW_BUILD_WAYLAND=$(usex wayland ON OFF))
mycmakeargs+=(-DGLFW_BUILD_X11=$(usex X ON OFF))
fi
cmake_src_configure
}
src_install() {
cmake_src_install
if use examples; then
dodoc -r "${S}"/examples/*
fi
}

1
media-libs/shaderc/Manifest Normal file
View file

@ -0,0 +1 @@
DIST shaderc-2024.1.tar.gz 227211 BLAKE2B a4c9790cb117e4cf2d528ed294ef0599dc3c17ac367a4f658254ff9e161f82b3338a2d70a033fabcdb7a2925c2f4668ee89cfff0d4b88cd2b22fcfb3f2786ea9 SHA512 017d8625c66da7eb5b431f595b27a4ddf146aaa12ef56777cb8c3f7f0f15eb01c3286e5905c5268de55d07cc19d5ffae4d4c08987d105b0a6be74616a467b736

13
media-libs/shaderc/files/shaderc-2020.4-fix-build.patch Normal file
View file

@ -0,0 +1,13 @@
diff --git a/libshaderc_util/src/compiler.cc b/libshaderc_util/src/compiler.cc
index c5ce37e..4703634 100644
--- a/libshaderc_util/src/compiler.cc
+++ b/libshaderc_util/src/compiler.cc
@@ -20,7 +20,7 @@
#include <thread>
#include <tuple>
-#include "SPIRV/GlslangToSpv.h"
+#include "glslang/SPIRV/GlslangToSpv.h"
#include "libshaderc_util/format.h"
#include "libshaderc_util/io.h"
#include "libshaderc_util/message.h"

11
media-libs/shaderc/metadata.xml Normal file
View file

@ -0,0 +1,11 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer type="person">
<email>sarnex@gentoo.org</email>
<name>Nick Sarnie</name>
</maintainer>
<upstream>
<remote-id type="github">google/shaderc</remote-id>
</upstream>
</pkgmetadata>

79
media-libs/shaderc/shaderc-2024.1-r1.ebuild Normal file
View file

@ -0,0 +1,79 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..13} )
inherit cmake-multilib python-any-r1
DESCRIPTION="Collection of tools, libraries and tests for shader compilation"
HOMEPAGE="https://github.com/google/shaderc"
EGIT_COMMIT="${PV}"
SRC_URI="https://github.com/google/${PN}/archive/v${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN}-${EGIT_COMMIT}"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="amd64 ~loong ppc64 ~riscv x86"
IUSE="doc"
RDEPEND="
~dev-util/glslang-1.3.290.0:=[${MULTILIB_USEDEP}]
~dev-util/spirv-tools-1.3.290.0[${MULTILIB_USEDEP}]
"
DEPEND="${RDEPEND}
${PYTHON_DEPS}
~dev-util/spirv-headers-1.3.290.0"
BDEPEND="doc? ( dev-ruby/asciidoctor )"
PATCHES=(
"${FILESDIR}"/${PN}-2020.4-fix-build.patch
)
# https://github.com/google/shaderc/issues/470
RESTRICT=test
src_prepare() {
cmake_comment_add_subdirectory examples
# Unbundle glslang, spirv-headers, spirv-tools
cmake_comment_add_subdirectory third_party
sed -i \
-e "s|\$<TARGET_FILE:spirv-dis>|${EPREFIX}/usr/bin/spirv-dis|" \
glslc/test/CMakeLists.txt || die
# Disable git versioning
sed -i -e '/build-version/d' glslc/CMakeLists.txt || die
# Manually create build-version.inc as we disabled git versioning
cat <<- EOF > glslc/src/build-version.inc || die
"${P}\n"
"$(best_version dev-util/spirv-tools)\n"
"$(best_version dev-util/glslang)\n"
EOF
cmake_src_prepare
}
multilib_src_configure() {
local mycmakeargs=(
-DSHADERC_SKIP_TESTS="true"
-DSHADERC_ENABLE_WERROR_COMPILE="false"
)
cmake_src_configure
}
multilib_src_compile() {
if multilib_is_native_abi && use doc; then
cmake_src_compile glslc_doc_README
fi
cmake_src_compile
}
multilib_src_install() {
if multilib_is_native_abi; then
use doc && local HTML_DOCS=( "${BUILD_DIR}/glslc/README.html" )
fi
cmake_src_install
}